#RT_GROUP_ICON = #RT_ICON + 11 

Global hMod.l 
Global path.s 
Structure ICONDIRENTRYCOMMON 
  bWidth.b        ; Width, in pixels, of the image 
  bHeight.b       ; Height, in pixels, of the image 
  bColorCount.b   ; Number of colors in image (0 if >=8bpp) 
  bReserved.b     ; Reserved ( must be 0) 
  wPlanes.w       ; Color Planes 
  wBitCount.w     ; Bits per pixel 
  dwBytesInRes.l  ; How many bytes in this resource? 
EndStructure 

Structure ICONDIRENTRY 
  common.ICONDIRENTRYCOMMON 
  dwImageOffset.l ; Where in the file is this image? 
EndStructure 

Structure ICONDIR 
  idReserved.w              ; Reserved (must be 0) 
  idType.w                  ; Resource Type (1 for icons) 
  idCount.w                 ; How many images? 
  idEntries.ICONDIRENTRY[0] ; An entry for each image (idCount of 'em) 
EndStructure 

Structure GRPICONDIRENTRY_ 
  common.ICONDIRENTRYCOMMON 
  nId.w ; the ID 
EndStructure 

Structure GRPICONDIR_ 
  idReserved.w                  ; Reserved (must be 0) 
  idType.w                      ; Resource type (1 for icons) 
  idCount.w                     ; How many images? 
  idEntries.GRPICONDIRENTRY_[0]  ; The entries for each image 
EndStructure 

Procedure ExtractGroupIcon(pIcon.l, IconFileName.s) 
  If CreateFile(0, IconFileName) 
  *iconGroup.GRPICONDIR_ = pIcon 
  IconHeaderSize.l = SizeOf(ICONDIR) + (*iconGroup\idCount*2) *SizeOf(ICONDIRENTRY) 
  *icon.ICONDIR = AllocateMemory(IconHeaderSize) 
  WriteData(0, *icon, IconHeaderSize) 
  *icon\idCount = *iconGroup\idCount 
  *icon\idReserved = *iconGroup\idReserved 
  *icon\idType = *iconGroup\idType 
  Offset.l = IconHeaderSize 
  LastSize.l = 0 
  For i = 0 To *iconGroup\idCount-1 
    *icon\idEntries[i]\common\bColorCount = *iconGroup\idEntries[i]\common\bColorCount 
    *icon\idEntries[i]\common\bHeight = *iconGroup\idEntries[i]\common\bHeight 
    *icon\idEntries[i]\common\bReserved = *iconGroup\idEntries[i]\common\bReserved 
    *icon\idEntries[i]\common\bWidth = *iconGroup\idEntries[i]\common\bWidth 
    *icon\idEntries[i]\common\dwBytesInRes = *iconGroup\idEntries[i]\common\dwBytesInRes 
    *icon\idEntries[i]\common\wBitCount = *iconGroup\idEntries[i]\common\wBitCount 
    *icon\idEntries[i]\common\wPlanes = *iconGroup\idEntries[i]\common\wPlanes 

    hRes = FindResource_(hMod, *iconGroup\idEntries[i]\nID, #RT_ICON) 
    If hRes 
     Offset + ResSize 
     hLoadRes = LoadResource_(hMod,   hRes); 
     ResSize = SizeofResource_(hMod, hRes) 
     *icon\idEntries[i]\common\dwBytesInRes = ResSize 
     *icon\idEntries[i]\dwImageOffset = Offset 
     WriteData(0, hLoadRes, ResSize) 
   EndIf 
 Next i 
 FileSeek(0, 0) 
 WriteData(0, *icon, SizeOf(ICONDIR)) 
 For i = 0 To *icon\idCount-1 
   WriteData(0, @*icon\idEntries[i]\common, SizeOf(ICONDIRENTRYCOMMON)) 
   WriteData(0, @*icon\idEntries[i]\dwImageOffset, 4) 
 Next i 
 CloseFile(0) 
 Else 
  MessageRequester("", "Can`t create file " + IconFileName, #MB_ICONERROR) 
EndIf 
FreeMemory(*icon) 
EndProcedure 

Procedure.l EnumResNameProc(ResHandle.L, ResType.L, ResName.L, AppParam.L) 
  If ResType = #RT_GROUP_ICON 
       hRes = FindResource_(hMod, ResName, ResType)    
       hLoadRes = LoadResource_(hMod,   hRes); 
       ResSize.l = SizeofResource_(hMod, hRes) 
       hLoadRes = LockResource_(hLoadRes) 
       ExtractGroupIcon(hLoadRes, path + "MAINICON.ico") 
       ProcedureReturn #False 
    EndIf 
  ProcedureReturn #True 
EndProcedure 

Procedure.L EnumResTypeProc(ResHandle.L, ResType.L, AppParam.L) 
  EnumResourceNames_(ResHandle, ResType, @EnumResNameProc(), 0) 
 ProcedureReturn #True 
EndProcedure 

file.s = "l:\__Small\_Готовые мелочи\Ресурсы\icons\bookConstants-x86.exe" 
path = GetPathPart(file) 
hMod = LoadLibrary_(file) 
If hMod 
  EnumResourceTypes_(hMod, @EnumResTypeProc(), 0) 
  FreeLibrary_(hMod) 
EndIf