EnableExplicit

;- Structure
Structure CharDB
  PrevChar$
  ThisIsCharEndWord.a
  Map Child.CharDB()
EndStructure

;- Variable
Global NewMap CharDB.CharDB()

Global CharDB.CharDB

#Win = 0
Enumeration Gadgets
  #String
  #Editor
  #Canvas
EndEnumeration

Procedure _Draw_Child( SearchText$, *Parent.CharDB = 0, cx = 20, cy = 20, NextChar = 0, PrevChar$ = "" )
  ForEach *Parent\Child()
    Protected Char$ = MapKey( *Parent\Child() )
    Protected Color = $C0C0C0
    If Char$ = Mid(SearchText$,NextChar,1) 
      _Draw_Child( SearchText$, *Parent\Child(), cx, cy + 30, NextChar + 1, Char$ )
      Color = $7FFF00
    EndIf
    RoundBox( cx-(TextWidth(Char$)/2)-2, cy-1, 20, 20, 20, 20, Color )
    DrawText( cx, cy, Char$, 0 )
    cx + 30
  Next
EndProcedure

Procedure _Draw_Demo( SearchText$ )
  StartDrawing(CanvasOutput(#Canvas))
  Box( 0, 0, OutputWidth(), OutputHeight(), $FFFFFF )
  Protected cx = 20, cy = 20
  Protected ch = TextWidth("W")
  DrawingMode(#PB_2DDrawing_Transparent)
  Protected Size = MapSize( CharDB() )
  Protected Char$ = ""
  Protected *Next.CharDB = 0
  ForEach CharDB()
    Char$ = MapKey( CharDB() )
    Protected Color = 0
    If Char$ = Left(SearchText$,1)
      *Next = CharDB()
      Color = $7FFF00
    Else
      Color = $C0C0C0
    EndIf
    RoundBox( cx-(TextWidth(Char$)/2)-2, cy-1, 20, 20, 20, 20, Color )
    DrawText( cx, cy, Char$, 0 )
    cx + 30
  Next
  cy + 30
  If *Next
    _Draw_Child( SearchText$, *Next, 20, 70, 2, *Next\PrevChar$ )
  EndIf
  StopDrawing()
EndProcedure

; если есть другой монитор, то окно появится на следующем от основного
Procedure _OpenWindow( Window, X, Y, Width, Height, Title$, Flags = #PB_Window_SystemMenu, ParentWindowID = 0, NumDesktop = 0 )
  If NumDesktop >= 0 And NumDesktop < ExamineDesktops()
    X + DesktopX(NumDesktop) : Y + DesktopY(NumDesktop)
    If Flags & #PB_Window_ScreenCentered
      X + ( DesktopWidth(NumDesktop)  / 2 ) - ( Width  / 2 )
      Y + ( DesktopHeight(NumDesktop) / 2 ) - ( Height / 2 )
      Flags ! #PB_Window_ScreenCentered
    EndIf
  EndIf
  ProcedureReturn OpenWindow( Window, X, Y, Width, Height, Title$, Flags, ParentWindowID )
EndProcedure
Macro OpenWindow : _OpenWindow : EndMacro


; Добавление слова в базу
Procedure Add( Word$ )
  Protected i, *Parent.CharDB = 0, PrevChar$ = ""
  For i = 1 To Len( Word$ )
    Protected Char$ = LCase( Mid( Word$, i, 1 ) )
    If Not *Parent
      If FindMapElement( CharDB(), Char$ )
        *Parent = CharDB()
      Else
        *Parent = AddMapElement( CharDB(), Char$ )
      EndIf
    Else
      If FindMapElement( *Parent\Child(), Char$ )
        *Parent = *Parent\Child()
      Else
        AddMapElement( *Parent\Child(), Char$ )
        *Parent\Child()\PrevChar$ = PrevChar$ ; текущая буква, будет знать о предыдущей
        If i >= Len(Word$)
          *Parent\Child()\ThisIsCharEndWord = #True ; указываем, что это конечный символ в слове
        EndIf
        *Parent = *Parent\Child()
      EndIf
    EndIf
    PrevChar$ = Char$
  Next
EndProcedure  

Procedure _Event_String_Edit()
  _Draw_Demo( GetGadgetText(#String) )
EndProcedure

Procedure _Event_Resize_Wondow()
  Protected w = WindowWidth(#Win), h = WindowHeight(#Win)
  ResizeGadget( #String, #PB_Ignore, #PB_Ignore, w-20, #PB_Ignore )
  ResizeGadget( #Editor, w-210, #PB_Ignore, #PB_Ignore, h-50 )
  ResizeGadget( #Canvas, #PB_Ignore, #PB_Ignore, w-230, h-50 )
EndProcedure

Global NewList Find$()

;- OpenWindow
If OpenWindow( #Win, 0, 0, 920, 620, "", #PB_Window_SystemMenu | #PB_Window_ScreenCentered | #PB_Window_MinimizeGadget | #PB_Window_MaximizeGadget | #PB_Window_SizeGadget, 0, 1 )
  StringGadget( #String, 10, 10, 900, 20, "" )
  EditorGadget( #Editor, 710, 40, 200, 570, #PB_Editor_ReadOnly )
  
  CanvasGadget( #Canvas, 10, 40, 690, 570 )
  
;   - добавление
  Add("Лазер")
  Add("Лазера")
  Add("Лазерам")
  Add("Лазерами")
  Add("Лазерах")
  Add("Лазере")
  Add("Лазеров")
  Add("Лазером")
  Add("Лазеру")
  Add("Лазеры")
  
  BindEvent( #PB_Event_SizeWindow, @_Event_Resize_Wondow(),#Win )
  BindGadgetEvent( #String, @_Event_String_Edit(), #PB_EventType_Change ) 
  
  _Draw_Demo("")
  SetActiveGadget(#String)
  
  Repeat
    Define Event = WaitWindowEvent()
  Until Event = #PB_Event_CloseWindow
  
EndIf

; указать своё расположение файла
XIncludeFile "purebasic-devel\PureBasicIDE\RadixTree.pb"

Define Tree.RadixTree

RadixInsert( @Tree, "Текст",    111 ) ; текст и его данные
RadixInsert( @Tree, "Текстов",  222 )
RadixInsert( @Tree, "Текстами", 333 )

; просмотр
Define NewList Test()
RadixEnumerateAll( Tree, Test() )

ForEach Test()
  Debug Test()
Next