EnableExplicit

;{ Simple Graph }

   ; Еще одна штука для простых "визуальных эффектов"
   ;   2017         (c) Luna Sole
   ;    v1.0.0.4       (+ взаимодействие с мышью)         
   

   ; Рисует график с двумя линиями на заданном изображении с использованием векторной библиотеки PB
   ; hImgOut            Изображение PB для рисования может быть любого размера [кроме, возможно, «очень низкого» разрешения ^^]
   ; GraphData()         массив с элементами для визуализации, должен содержать как минимум 1 элемент [начиная с 0]
   ; OutGeoData()         map для получения данных, необходимых для обработки взаимодействия с мышью. map key = координата X на изображении графика, value = связанный индекс GraphData()
   ; Average            сколько элементов используется для расчета среднего значения для текущего элемента? 2 минимально, если меньше будет отключено
   ; GridStepX            Шаг сетки X [вертикальные линии], измеренное в количестве GraphData (). используйте 0 для отключения
   ; GridStepY            Шаг сетки Y [горизонтальные линии], измеренное в значениях GraphData (). 0 для отключения
   ; FontSize            размер шрифта текстовых меток. используйте 0, чтобы отключить метки
   ; ColorN            цвета для элементов графика (RGB)
   ; RETURN:            нет, изображение изменено в случае успеха
   Procedure DrawSimpleGraph (hImgOut, Array GraphData(1), Map OutGeoData(), Average, GridStepX = 10, GridStepY = 10, FontSize = 9, Color1 = $00DDDD, Color2 = $DDDD00)
      ClearMap(OutGeoData())                  ; сбросить данные мыши
      
      Protected maxItems = ArraySize(GraphData())   ; количество пунктов (X)
      Protected maxValues                     ; количество значений (Y)
      Protected highValue, lowValue            ; самые высокие и самые низкие значения GraphData
      Protected t                           ; общая временная переменная
      If maxItems < 0 : ProcedureReturn :   EndIf   ; выйти, если массив GraphData недействителен

      ; Найти минимум и максимум значений, чтобы трансформировать шкалу
      Protected Dim TData(0)
      CopyArray(GraphData(), TData())
      SortArray(TData(), #PB_Sort_Ascending)
      lowValue = TData(0)
      highValue = TData(maxItems)
      FreeArray(TData())
      
      ; сделать вещи, чтобы лучше подогнать фоновую сетку
      If GridStepY > 0
         If highValue >= 0
            highValue + GridStepY - highValue % GridStepY
         ElseIf highValue
            highValue - highValue % GridStepY
         EndIf
         If lowValue > 0
            lowValue  - lowValue  % GridStepY
         ElseIf lowValue < 0
            lowValue  - (GridStepY + lowValue  % GridStepY)
         EndIf
      EndIf
      maxValues = highValue - lowValue
      If maxValues <= 0
         maxValues = 1
      EndIf
      ; загрузить шрифт для текстовых меток
      Protected Font
      If FontSize > 0
         Font = LoadFont(#PB_Any, "arial", FontSize)
         If Not IsFont(Font) ; и так далее
            Font = LoadFont(#PB_Any, "tahoma", FontSize)
            If Not IsFont(Font) ; и так далее.. :)
               Font = LoadFont(#PB_Any, "consolas", FontSize)
            EndIf
         EndIf
      EndIf
      
      ; рисовать данные в изображение
      If StartVectorDrawing(ImageVectorOutput(hImgOut, #PB_Unit_Pixel))
         ; [n] - определить смещения графиков / размеры текстовых меток и т. д.
         Protected.d oX = 1.0, oY = oX
         Protected.d mtW = 1.0, mtH = mtW
         If IsFont(Font)
            VectorFont(FontID(Font), FontSize)
            If VectorTextWidth(Str(highValue)) > VectorTextWidth(Str(lowValue)) ; задаём ширину текста
               oX = VectorTextWidth(Str(highValue)) + 2.0
            Else
               oX = VectorTextWidth(Str(lowValue)) + 2.0
            EndIf
            oY = VectorTextHeight("0A") + 2.0
            If oX > oY
               oY = oX
            Else
               oX = oY
            EndIf
            mtW = VectorTextWidth(Str(maxItems)) * 1.2
            mtH = VectorTextHeight(Str(highValue)) * 0.8
         EndIf
         ;    ширина линии (в пикселях)
         Protected.d LineWidth = 1.0
         ;    множители для масштабирования координат графика
         Protected.d mX = (VectorOutputWidth() - oX * 2.0) / (maxItems + Bool(maxItems = 0))   
         Protected.d mY = (VectorOutputHeight() - oY * 2.0) / maxValues
         ;   временные переменные, используемые при рисовании
         Protected.d cX, cY
         
         ; [0] - рисовать текстовые метки и линии сетки
         VectorSourceColor($77FFFFFF) ; цвет меток и сетки шкалы
         Protected.d tLast
         ;   горизонтальные линии / метки
         tLast = oY + maxValues * mY + 5.0
         If GridStepY > 0
            For t = maxValues To 0 Step -1
               If t % GridStepY = 0 Or t = maxValues
                  cY = oY + t * mY
                  ; нарисовать текстовую метку
                  If IsFont(Font) And cY < tLast
                     MovePathCursor(oX - (2.0 + VectorTextWidth(Str(highValue - t))), cY - VectorTextHeight(Str(highValue - t)) * 0.5)
                     DrawVectorText(Str(highValue - t))
                     tLast = cY - mtH
                  EndIf
                  ; нарисовать линию сетки
                  MovePathCursor(oX, oY + mY * t)            
                  AddPathLine(oX + maxItems * mX, oY + mY * t)
               EndIf
            Next t
         EndIf
         ;   вертикальные линии / метки
         tLast = 0.0
         If GridStepX > 0   
            ;GridStepX + 1
            For t = 0 To maxItems
               If t % GridStepX = 0 Or t = maxItems
                  cX = oX + t * mX
                  cY = oY + maxValues * mY
                  ; нарисовать текстовую метку
                  If IsFont(Font) And cX > tLast
                     MovePathCursor(cX - VectorTextWidth(Str(t)) * 0.5, cY + 2.0)
                     DrawVectorText(Str(t))
                     tLast = cX + mtW
                  EndIf
                  ; нарисовать линию сетки
                  MovePathCursor(cX, oY)
                  AddPathLine(cX, cY)
               EndIf
            Next t
         EndIf
         ;   fin
         If GridStepX > 0 Or GridStepY > 0
            DashPath(1.0, 3.0)
         EndIf
         
         
         ; [1] - нарисуйте основную линию / элементы и сформируйте "геоданные"
         Protected.d gX = oX
         Protected.d gX2
         VectorSourceColor(Color1 | $FF000000)
         MovePathCursor(oX, oY + mY * (highValue - GraphData(0)))
         For t = 0 To maxItems
            cX = oX + mX * t
            cY = oY + mY * (highValue - GraphData(t))
            AddPathLine(cX, cY)         ; добавить линию
            AddPathCircle(cX, cY, 2.0)  	; добавить точку
            MovePathCursor(cX, cY)      ; восстановить позицию курсора
            
            ; построить те "геоданные", которые используются для работы с мышью
            gX2 = gX + (cX - gX) * 0.5
            While gX < gX2
               OutGeoData(Str(Int(gX))) = t - 1
               gX + 1.0
            Wend
            While gX < cX
               OutGeoData(Str(Int(gX))) = t
               gX + 1.0
            Wend
            gX = cX
         Next t
         StrokePath(LineWidth)
         
         
         ; [2] - нарисовать «тренд» / усредненную линию
         Protected NewList Avg() ; стек для хранения последних значений
         Protected.d Avg         ; рассчитать текущий результат
         If Average > maxItems + 1
            Average = maxItems + 1
         EndIf
         If Average > 1            ; имеет смысл рисовать, только если он больше 1
            While ListSize(Avg()) < Average
               AddElement(Avg())   ; 'экстраполировать' с использованием данных первого элемента, без этого все выглядит хуже для меня: 3
               Avg() = GraphData(0)
            Wend
            MovePathCursor(oX, oY + (highValue - GraphData(0)) * mY)
            For t = 0 To maxItems
               FirstElement(Avg())      ; все это работает как стековая структура с максимальной глубиной = Average
               DeleteElement(Avg())   
               LastElement(Avg())      
               AddElement(Avg())
               Avg() = GraphData(t)   ; нажать новый элемент
               Avg = 0.0            ; рассчитать среднее значение по последним элементам
               ForEach Avg()
                  Avg + Avg()
               Next
               cX = oX + mX * t
               cY = oY + (highValue - Avg / Average) * mY
               AddPathLine(cX, cY)  ; добавить линию
               AddPathCircle(cX, cY, 1.0) 	; добавить точку
               MovePathCursor(cX, cY)      ; восстановить позицию курсора
            Next t
            VectorSourceColor(Color2 | $FF000000)
            StrokePath(LineWidth)
         EndIf
         
         ; очистить
         FreeList(Avg())
         StopVectorDrawing()
      EndIf
      
      ; очистить
      If IsFont(Font)
         FreeFont(Font)
      EndIf
   EndProcedure
   
;}


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Тест / пример
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


; используется для обработки кликов мыши по графику
; mapkey - координата X изображения графика, value - соответствующий индекс в массиве GraphData()
Global NewMap GraphGeodata()

; Размеры графика
Global W = 800, H = 600
; Изображение для рисования графика
Global tImg
; Окно и холст для отображения графика
Global tWindow, tCanvas


; Эта процедура обрабатывает события мыши на холсте графика.
Procedure GraphCB()
   Protected cX = GetGadgetAttribute(tCanvas, #PB_Canvas_MouseX)
   Select EventType()
      Case #PB_EventType_LeftButtonDown:
         If FindMapElement(GraphGeodata(), Str(cX))
            Debug "Нажата левая кнопка мыши  " + GraphGeodata()
         EndIf
      Case #PB_EventType_LeftButtonUp:
         If FindMapElement(GraphGeodata(), Str(cX))
            Debug "Отпущена левая кнопка мыши  " + GraphGeodata()
         EndIf
      Case #PB_EventType_LeftClick:
         If FindMapElement(GraphGeodata(), Str(cX))
            Debug "Клик левой кнопкой мыши " + GraphGeodata()
         EndIf
         
      Case #PB_EventType_RightButtonDown:
         If FindMapElement(GraphGeodata(), Str(cX))
            Debug "Нажата правая кнопка мыши " + GraphGeodata()
         EndIf
      Case #PB_EventType_RightButtonUp:
         If FindMapElement(GraphGeodata(), Str(cX))
            Debug "Отпущена правая кнопка мыши " + GraphGeodata()
         EndIf
      Case #PB_EventType_RightClick:
         If FindMapElement(GraphGeodata(), Str(cX))
            Debug "Клик правой кнопкой мыши " + GraphGeodata()
         EndIf
         
      Case #PB_EventType_MouseMove:
         If FindMapElement(GraphGeodata(), Str(cX))
            Debug "Мышь наведена на элемент " + GraphGeodata()
         EndIf
   EndSelect
EndProcedure

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; сгенерировать графические данные
Dim GraphValues (127) ; размер массива определяет число точек по оси Y
Define t
Define j=0
For t = 0 To ArraySize(GraphValues())
; 	GraphValues(t) =Pow(t , 2)
; 	GraphValues(t) =60 * Cos(Radian(j-90))
	GraphValues(t) =60 * Sin(Radian(j-90))
	j+5
Next t

; создать изображение для получения вывода
tImg = CreateImage(#PB_Any, W, H, 32, $1B1B1B) ; цвет фона тут
; нарисовать график на созданном изображении
DrawSimpleGraph(tImg, GraphValues(), GraphGeodata(), 0, 10, 10, 12)

; рисуем ещё поверх
j=0
For t = 0 To ArraySize(GraphValues())
; 	GraphValues(t) =Pow(t , 2)
	GraphValues(t) =60 * Cos(Radian(j-90))
; 	GraphValues(t) =60 * Sin(Radian(j-90))
	j+5
Next t
DrawSimpleGraph(tImg, GraphValues(), GraphGeodata(), 0, 10, 10, 12, $80A800)

; рисуем ещё поверх
j=0
For t = 0 To ArraySize(GraphValues())
; 	GraphValues(t) =Pow(t , 2)
; 	GraphValues(t) =60 * Cos(Radian(j-90))
	GraphValues(t) = - 60 * Sin(Radian(j-90))
	j+5
Next t
DrawSimpleGraph(tImg, GraphValues(), GraphGeodata(), 0, 10, 10, 12, $9900FF)

; рисуем ещё поверх
; For t = 0 To ArraySize(GraphValues())
	; 	GraphValues(t) = t * 0.8 - 60 ; линия наклонная
; 	GraphValues(t) = 60*Exp(- t / 24) ; экпонента
; 	GraphValues(t) =60 * Abs(Sin(Radian(j-90)))
; Next t
; DrawSimpleGraph(tImg, GraphValues(), GraphGeodata(), 0, 10, 10, 12, $80A800)

; показать
tWindow = OpenWindow(#PB_Any, 0, 0, W, H, "График", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
tCanvas = CanvasGadget(#PB_Any, 0, 0, W, H)
SetGadgetAttribute(tCanvas, #PB_Canvas_Image, ImageID(tImg))
; привязать события, необходимые для взаимодействия с мышью
; BindEvent(#PB_Event_Gadget, @GraphCB(), tWindow, tCanvas, #PB_All)

; освободить изображение
FreeImage(tImg)

Repeat
Until WaitWindowEvent() = #PB_Event_CloseWindow