PureBasic - форум

Пётр · Поделиться**331**19.02.2011 22:11:06

Arei написал(а):

а как его принять

В справке ведь написано что с помощью функции EventType()

Код:

  If OpenWindow(0, 0, 0, 600, 300, "WebGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    WebGadget(0, 10, 10, 580, 280, "http://www.purebasic.com")
    ; Note: if you want to use a local file, change last parameter to "file://" + path + filename
    Repeat
      Event=WaitWindowEvent()
      If Event = #PB_Event_Gadget
        If EventGadget() = 0
          If EventType() = #PB_EventType_DownloadEnd
            Debug "Страница загружена"
          EndIf
        EndIf
      EndIf
    Until Event = #PB_Event_CloseWindow
  EndIf

0

Arei · Поделиться**332**19.02.2011 23:22:13

Спасибо отличный пример, но только интересно почему когда я пытаюсь при полной загрузке страницы перезагрузить её,то ничего не получается.

0

Илья · Поделиться**333**19.02.2011 23:31:54

Код:

  If OpenWindow(0, 0, 0, 245, 105, "ImageGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    If LoadImage(0, "q.jpg") 
      ImageGadget(0,  10, 10, 100, 83, ImageID(0))                    
      ImageGadget(1, 130, 10, 100, 83, ImageID(0), #PB_Image_Border)    
    EndIf
    Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
  EndIf

Эгзэшник этой программы находится в той же папки что и файл q.jpg. Но почемуто когда я запускаю эгзэшник на экран выходит пустое окно. А почему?

0

mirashic · Поделиться**334**19.02.2011 23:55:47

Забыл UseJPEGImageDecoder() перед кодом

Справка:

Код:

Result = LoadImage( #Image, Filename$ [, Flags] )

Эти функции позволяют использовать дополнительные форматы изображений: 
Внимание: эти функции должны быть вызваны перед загрузкой изображений соответствующих типов: 

UseJPEGImageDecoder() 
UseJPEG2000ImageDecoder() 
UsePNGImageDecoder() 
UseTIFFImageDecoder() 
UseTGAImageDecoder()

Отредактировано mirashic (20.02.2011 00:01:12)

0

Arei · Поделиться**335**20.02.2011 00:14:17

Скажите SetGadgetText(#WebGadget, "Адрес ссылки") а если я не знаю ссылку на сайте, как мне сделать это и предидущий вопрос.Спасибо за помощь.

0

Пётр · Поделиться**336**20.02.2011 01:26:48

Arei написал(а):

Спасибо отличный пример, но только интересно почему когда я пытаюсь при полной загрузке страницы перезагрузить её,то ничего не получается.

Как перезагружаешь?

0

Arei · Поделиться**337**20.02.2011 10:19:29

SetGadgetState(0,#PB_Web_Refresh)
вот так

0

Пётр · Поделиться**338**20.02.2011 16:32:23

Arei написал(а):

SetGadgetState(0,#PB_Web_Refresh)
вот так

Так работает!

Код:

  If OpenWindow(0, 0, 0, 600, 300, "WebGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    WebGadget(0, 10, 10, 580, 280, "http://www.purebasic.com")
    ; Note: if you want to use a local file, change last parameter to "file://" + path + filename
    x=0
    Repeat
      Event=WaitWindowEvent()
      If Event = #PB_Event_Gadget
        If EventGadget() = 0
          If EventType() = #PB_EventType_DownloadEnd
            If x=1
              Debug "Страница загружена"
              SetGadgetState(0,#PB_Web_Refresh)
            EndIf
            x=1
          EndIf
        EndIf
      EndIf
    Until Event = #PB_Event_CloseWindow
  EndIf

0

Arei · Поделиться**339**20.02.2011 16:36:04

спасибо уважаемый,все работает как часы.

0

Илья · Поделиться**340**21.02.2011 20:25:32

Код:

 If OpenWindow(0, 0, 0, 140, 110, "OptionGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)


    CheckBoxGadget(0, 30, 45, 60, 20, "")
 
    Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
 
  EndIf 
  Debug GetGadgetState(0)

эта программа даёт возможность поставить галочку, а мне надо чтобы галачка была поставлена с самого начала. Как это зделать?

0

Пётр · Поделиться**341**21.02.2011 21:04:18

Илья написал(а):

надо чтобы галачка была поставлена с самого начала.

Код:

 If OpenWindow(0, 0, 0, 140, 110, "OptionGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)


    CheckBoxGadget(0, 30, 45, 60, 20, "")
    SetGadgetState(0, 1)
 
    Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
 
  EndIf 
  Debug GetGadgetState(0)

0

Илья · Поделиться**342**22.02.2011 01:03:59

Код:

OpenWindow (0,50,50,200,200,"okno",#PB_Window_SystemMenu | #PB_Window_ScreenCentered)
StringGadget (1,10,10,170,40,"")
 Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow

в этой программе запрашивается ввод данных с клавиатуры, и эти данные могут быть любыми. И цифрами, и буквами, и всеми любыми символами. А как ограничить ввод, например чтоб все цифры вводились, а например буквы не вводились?

0

Пётр · Поделиться**343**22.02.2011 01:15:02

Илья написал(а):

А как ограничить ввод, например чтоб все цифры вводились

В справке на StringGadget об этом написано.

Код:

OpenWindow (0,50,50,200,200,"okno",#PB_Window_SystemMenu | #PB_Window_ScreenCentered)
StringGadget (1,10,10,170,40,"", #PB_String_Numeric)
Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow

0

Илья · Поделиться**344**22.02.2011 01:22:01

Пётр, вообщето мне нужно немного другое, эта функция ограничивает только на буквы, а мне надо чуть другое. Например цифру 0 вводить нельзя и т. п.

0

Пётр · Поделиться**345**22.02.2011 11:41:24

Илья написал(а):

Например цифру 0 вводить нельзя и т. п.

Тогда нужно сделать как здесь.

0

goodwen · Поделиться**346**22.02.2011 21:00:17

Здравствуйте, у меня вот есть такая строка в коде

Код:

If FindString(poisk.s, "слово1", 1)<>0 or FindString(poisk.s, "слово2", 1)<>0

Как мне сделать так, чтобы если в строке найдётся одно из этих двух слов(слово1 и слово2), присвоить отдельной строковой переменной то слово, которое нашлось (то есть это либо "слово1", либо "слово2")? Так вообще можно сделать? Потому что слово1 и 2 это именно не переменные.

0

Пётр · Поделиться**347**22.02.2011 21:38:33

Код:

String.s=""
If FindString(poisk.s, "слово1", 1)<>0 
  String="слово1"
ElseIf FindString(poisk.s, "слово2", 1)<>0
  String="слово2"
EndIf

0

Alex · Поделиться**348**23.02.2011 02:15:09

Народ, подскажите пожалуста, например у меня есть переменная с записаным в неё числом и мне надо узнать сколько символов в этом числе. А как это сделать?

0

mirashic · Поделиться**349**23.02.2011 08:24:17

Раздел справки: String
Переводиш число в строку String$= Str(Value.q)
и применяешь функцию Length = Len(String$)

0

max · [1985-03-29]

Всем привет!
Такой вопрос: можно ли как-то считать скан коды клавиатуры ноутбука? Стандартными сниферами это сделать нельзя, так как клава PC/2.
Заранее спасибо!

0

Пётр · Поделиться**351**25.02.2011 21:41:42

max написал(а):

можно ли как-то считать скан коды клавиатур

Код:

OpenWindow(0,0,0,230,150,"", #PB_Window_SystemMenu | #PB_Window_ScreenCentered) 
EditorGadget(0,10,10,210,130 )
Repeat
  Event=WaitWindowEvent()
  If Event=#WM_KEYDOWN ; Была нажата кнопка
    AddGadgetItem(0,-1,Str( EventwParam())+"  " ) ; Помещаем её код в редактор
    SendMessage_(GadgetID(0),#EM_SETSEL,-1,-1) ; Прокрутка текста
  EndIf
Until Event=#PB_Event_CloseWindow

0

max · [1985-03-29]

Спасибо!

0

Alex · Поделиться**353**26.02.2011 23:24:42

Код:

OpenWindow(0, 100, 200, 195, 260, "window")
CreateMenu(0, WindowID(0))
MenuItem(1, "help")
     Repeat
      E = WaitWindowEvent(0)

If e= #PB_Event_Menu
OpenWindow(1, 500, 200, 155, 200, "help")
Repeat
r = WaitWindowEvent(0)
If r=#PB_Event_CloseWindow
qwe=123
CloseWindow(1)
EndIf
Until qwe=123
EndIf
Until e=#PB_Event_CloseWindow

В этой программе появляется окно с маленьким меню состоящим из одного пункта. Когда я нажимаю на пункт то появляется ещё одно окно (пустое). Его можно закрыть. Но когда это 2-е окно открываешь 2 раз и закрываешь то закрывается не только это окно, но и 1-е тоже. А почему это возникает и как это исправить?

0

mirashic · Поделиться**354**26.02.2011 23:41:58

Можно так:

Код:

OpenWindow(0,100, 200,380,200,"Окно")
 CreateMenu(0, WindowID(0))
 MenuItem(1, "help")
 

Repeat
Event =  WaitWindowEvent() 

 Select Event
    Case #PB_Event_CloseWindow
     If EventWindow()=0
      Break  
     EndIf 
     If EventWindow()=1
      CloseWindow(1)
     EndIf 
   Case #PB_Event_Menu
    OpenWindow(1, 500, 200, 155, 200, "help")
   Case #PB_Event_Gadget
    Select EventGadget()
     Case 3
     Case 4
     Case 5
   EndSelect             
EndSelect  

ForEver

Код:

OpenWindow(0, 100, 200, 195, 260, "window")
CreateMenu(0, WindowID(0))
MenuItem(1, "help")
Repeat
Event = WaitWindowEvent(0)

 If Event= #PB_Event_Menu
  OpenWindow(1, 500, 200, 155, 200, "help")
 EndIf
 
  If Event=#PB_Event_CloseWindow
   If EventWindow()=0
    Break
   EndIf
  If EventWindow()=1
    CloseWindow(1)
   EndIf
  EndIf
  
ForEver

Отредактировано mirashic (26.02.2011 23:48:46)

0

Alex · Поделиться**355**27.02.2011 00:21:11

Спасибо

0

Alex · Поделиться**356**27.02.2011 00:38:16

А вот у меня есть 2 окна. В 1 окне мне нужно разместить какойнибудь гаджет. Но гаджеты часто размещаются не в том окне которое мне нужно. А как настроить, в каком окне разместится гаджет?

0

Пётр · Поделиться**357**27.02.2011 00:45:43

Гаджеты размещаются в окне, созданном последним.
С помощью функции UseGadgetList, можно выбрать окно, в которому будут размещаться гаджеты.
Вот пример из справки:

Код:

  If OpenWindow(0, 0, 0, 500, 500, "Main Window", #PB_Window_SystemMenu|#PB_Window_ScreenCentered)
    ButtonGadget(0, 10, 10, 150, 25, "Button 1")
    
    ; Create Window with #PB_Window_NoGadgets to prevent automatic GadgetList creation
    If OpenWindow(1, 0, 0, 300, 200, "Child Window", #PB_Window_TitleBar|#PB_Window_WindowCentered|#PB_Window_NoGadgets, WindowID(0))     
      OldGadgetList = UseGadgetList(WindowID(1)) ; Create GadgetList and store old GadgetList
      
      ButtonGadget(10, 10, 10, 150, 25, "Child Window Button")
      
      UseGadgetList(OldGadgetList)               ; Return to previous GadgetList
    EndIf
    
    ButtonGadget(1, 10, 45, 150, 25, "Button 2") ; This will be on the main window again
    
    Repeat
    Until WaitWindowEvent() = #PB_Event_CloseWindow
  EndIf

0

neo · Поделиться**358**27.02.2011 10:24:53

А можно ли делать асм /Си вставки в коды пурика

P.S жетельно примеры , си интересует больше

Отредактировано neo (27.02.2011 10:27:35)

0

Пётр · Поделиться**359**27.02.2011 11:51:23

Асм можно, а Си нет.
Пример на асме из справки

Код:

Procedure Test(*Pointer, Variable)
    ! MOV dword [p.p_Pointer], 20
    ! MOV dword [p.v_Variable], 30
    Debug *Pointer
    Debug Variable
EndProcedure
  
Test(0, 0)

Если хочется использовать часть кода на Си, создай из него DLL и вызывай из программы.

0

neo · Поделиться**360**27.02.2011 12:58:56

Спасибо

0

Какая версия?	OffTop	03.10.2021
Мне постоянно пищет вот это	Вопросы по PureBasic	14.10.2011
Размер экрана в пикселях	Вопросы по PureBasic	13.02.2011
консоль	Вопросы по PureBasic	19.03.2015
Полноэкранные приложения на purebasic	Вопросы по PureBasic	08.03.2011

PureBasic - форум

Меню навигации

Пользовательские ссылки

Информация о пользователе

Вопросы новичка (продолжение…)

Сообщений 331 страница 360 из 990

Поделиться33119.02.2011 22:11:06

Поделиться33219.02.2011 23:22:13

Поделиться33319.02.2011 23:31:54

Поделиться33419.02.2011 23:55:47

Поделиться33520.02.2011 00:14:17

Поделиться33620.02.2011 01:26:48

Поделиться33720.02.2011 10:19:29

Поделиться33820.02.2011 16:32:23

Поделиться33920.02.2011 16:36:04

Поделиться34021.02.2011 20:25:32

Поделиться34121.02.2011 21:04:18

Поделиться34222.02.2011 01:03:59

Поделиться34322.02.2011 01:15:02

Поделиться34422.02.2011 01:22:01

Поделиться34522.02.2011 11:41:24

Поделиться34622.02.2011 21:00:17

Поделиться34722.02.2011 21:38:33

Поделиться34823.02.2011 02:15:09

Поделиться34923.02.2011 08:24:17

Поделиться35025.02.2011 20:16:47

Поделиться35125.02.2011 21:41:42

Поделиться35225.02.2011 22:12:27

Поделиться35326.02.2011 23:24:42

Поделиться35426.02.2011 23:41:58

Поделиться35527.02.2011 00:21:11

Поделиться35627.02.2011 00:38:16

Поделиться35727.02.2011 00:45:43

Поделиться35827.02.2011 10:24:53

Поделиться35927.02.2011 11:51:23

Поделиться36027.02.2011 12:58:56

Похожие темы