Procedure RunOnce_Startup()
	Protected Result, files$, TargetWnd, Mutex$, Count, i, copydata.COPYDATASTRUCT ; , RunOnceMutex
	Result = #False ; не выходить из редактора
	; 	мы можем создать мьютекс с путём к программе, это быстрее
	Mutex$ = ReplaceString(ProgramFilename(), "\", "|")

; 	RunOnceMutex = CreateMutex_(0, 0, Mutex$)
	CreateMutex_(0, 0, Mutex$)

; 	если мьютекс существует, то... то отправляем данные существующей программе
	If GetLastError_() = #ERROR_ALREADY_EXISTS
    Result = #True ; закрыть редактор после этого
    Count = CountProgramParameters()
    If Count
    	; временное окно до открытия окон, которое тут же будет закрыто, поэтому его id не важен
    	If OpenWindow(0, 0, 0, 0, 0, "", #PB_Window_Invisible)

        For i = 0 To Count - 1
        	files$ + ProgramParameter(i) + Chr(10)
        Next
        files$ = RTrim(files$, Chr(10))

        copydata\dwData = #pble
        copydata\cbData = (Len(files$) + 1) * #CharSize	 ; include null
        copydata\lpData = @files$
        TargetWnd = WinGetHandle()
        SendMessage_(TargetWnd, #WM_COPYDATA, WindowID(0), @copydata)
        CloseWindow(0)
        SetForegroundWindow(TargetWnd)

    	EndIf
    EndIf
	EndIf

	ProcedureReturn Result
EndProcedure

Procedure MyWindowCallback(WindowID, Message, WParam, lParam)
	Protected Result, *copydata.COPYDATASTRUCT
	Result = #PB_ProcessPureBasicEvents
	; событие WM_COPYDATA - произошла передача данных
	If Message = #WM_COPYDATA
    *copydata.COPYDATASTRUCT = lParam
    If *copydata\dwData = #pble And *copydata\cbData > 0
    	;     	g_SendFiles$ =
;     	MessageRequester("", PeekS(*copydata\lpData, *copydata\cbData / #CharSize))
    	DropFiles(PeekS(*copydata\lpData, *copydata\cbData / #CharSize))
    	Result = #True
    EndIf
	EndIf
	ProcedureReturn Result
EndProcedure
CompilerEndIf